Merge static_world and web_server examples

The new example is called file_server and it's basically the same as web_server was. The name is clearer than the original, all examples being "Web servers". The new example is also tested and the test suite has been refactored a little.
2025-07-14 20:30:23 +00:00 · 2016-06-13 13:23:22 +02:00 · 2016-06-13 13:23:22 +02:00 · 88227898ed
commit 88227898ed
parent 4293a40d9e
26 changed files with 181 additions and 180 deletions
--- a/examples/file_server/src/directory_handler.erl
+++ b/examples/file_server/src/directory_handler.erl
@ -0,0 +1,47 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @doc Directory handler.
+-module(directory_handler).
+
+%% REST Callbacks
+-export([init/2]).
+-export([allowed_methods/2]).
+-export([resource_exists/2]).
+-export([content_types_provided/2]).
+
+%% Callback Callbacks
+-export([list_json/2]).
+-export([list_html/2]).
+
+init(Req, Paths) ->
+	{cowboy_rest, Req, Paths}.
+
+allowed_methods(Req, State) ->
+	{[<<"GET">>], Req, State}.
+
+resource_exists(Req, {ReqPath, FilePath}) ->
+	case file:list_dir(FilePath) of
+		{ok, Fs} -> {true, Req, {ReqPath, lists:sort(Fs)}};
+		_Err -> {false, Req, {ReqPath, FilePath}}
+	end.
+
+content_types_provided(Req, State) ->
+	{[
+		{{<<"text">>, <<"html">>, []}, list_html},
+		{{<<"application">>, <<"json">>, []}, list_json}
+	], Req, State}.
+
+list_json(Req, {Path, Fs}) ->
+	Files = [ <<(list_to_binary(F))/binary>> || F <- Fs ],
+	{jsx:encode(Files), Req, Path}.
+
+list_html(Req, {Path, Fs}) ->
+	Body = [[ links(Path, F) || F <- [".."|Fs] ]],
+	HTML = [<<"<!DOCTYPE html><html><head><title>Index</title></head>",
+		"<body>">>, Body, <<"</body></html>\n">>],
+	{HTML, Req, Path}.
+
+links(<<>>, File) ->
+	["<a href='/", File, "'>", File, "</a><br>\n"];
+links(Prefix, File) ->
+	["<a href='/", Prefix, $/, File, "'>", File, "</a><br>\n"].
--- a/examples/file_server/src/directory_lister.erl
+++ b/examples/file_server/src/directory_lister.erl
@ -0,0 +1,32 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(directory_lister).
+-behaviour(cowboy_middleware).
+
+-export([execute/2]).
+
+execute(Req, Env=#{handler := cowboy_static}) ->
+	redirect_directory(Req, Env);
+execute(Req, Env) ->
+	{ok, Req, Env}.
+
+redirect_directory(Req, Env=#{handler_opts := {_, _, _, Extra}}) ->
+	Path = cowboy_req:path_info(Req),
+	Path1 = << <<S/binary, $/>> || S <- Path >>,
+	{dir_handler, DirHandler} = lists:keyfind(dir_handler, 1, Extra),
+	FullPath = resource_path(Path1),
+	case valid_path(Path) and filelib:is_dir(FullPath) of
+		true -> handle_directory(Req, Env, Path1, FullPath, DirHandler);
+		false -> {ok, Req, Env}
+	end.
+
+handle_directory(Req, Env, Prefix, Path, DirHandler) ->
+	{ok, Req, Env#{handler => DirHandler, handler_opts => {Prefix, Path}}}.
+
+valid_path([]) -> true;
+valid_path([<<"..">> | _T]) -> false;
+valid_path([<<"/", _/binary>> | _T]) -> false;
+valid_path([_H | Rest]) -> valid_path(Rest).
+
+resource_path(Path) ->
+	filename:join([code:priv_dir(file_server), Path]).
--- a/examples/file_server/src/file_server_app.erl
+++ b/examples/file_server/src/file_server_app.erl
@ -0,0 +1,29 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(file_server_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+	Dispatch = cowboy_router:compile([
+		{'_', [
+			{"/[...]", cowboy_static, {priv_dir, file_server, "", [
+				{mimetypes, cow_mimetypes, all},
+				{dir_handler, directory_handler}
+			]}}
+		]}
+	]),
+	{ok, _} = cowboy:start_clear(http, 100, [{port, 8080}], #{
+		env => #{dispatch => Dispatch},
+		middlewares => [cowboy_router, directory_lister, cowboy_handler]
+	}),
+	file_server_sup:start_link().
+
+stop(_State) ->
+	ok.
--- a/examples/file_server/src/file_server_sup.erl
+++ b/examples/file_server/src/file_server_sup.erl
@ -0,0 +1,23 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(file_server_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+	supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	Procs = [],
+	{ok, {{one_for_one, 10, 10}, Procs}}.