Initial WebTransport implementation

This implements the upcoming draft-13 but has bits to make it work with draft-02 that most (all?) Chromium versions use. Data and events are not going through cowboy_stream beyond init. Since this approach appears to work well it may be a good idea to do the same for Websocket over HTTP/2+ and improve its performance.
2025-07-13 20:00:24 +00:00 · 2025-05-12 13:01:55 +02:00 · 2025-05-12 13:01:55 +02:00 · 58909b0144
commit 58909b0144
parent 24d32de931
13 changed files with 1574 additions and 22 deletions
--- a/2
+++ b/2
@ -16,7 +16,7 @@ CT_OPTS += -ct_hooks cowboy_ct_hook [] # -boot start_sasl
 LOCAL_DEPS = crypto

 DEPS = cowlib ranch
-dep_cowlib = git https://github.com/ninenines/cowlib 2.14.0
+dep_cowlib = git https://github.com/ninenines/cowlib webtransport
 dep_ranch = git https://github.com/ninenines/ranch 1.8.1

 ifeq ($(COWBOY_QUICER),1)
--- a/ebin/cowboy.app
+++ b/ebin/cowboy.app
@ -1,7 +1,7 @@
 {application, 'cowboy', [
 	{description, "Small, fast, modern HTTP server."},
 	{vsn, "2.13.0"},
-	{modules, ['cowboy','cowboy_app','cowboy_bstr','cowboy_children','cowboy_clear','cowboy_clock','cowboy_compress_h','cowboy_constraints','cowboy_decompress_h','cowboy_handler','cowboy_http','cowboy_http2','cowboy_http3','cowboy_loop','cowboy_metrics_h','cowboy_middleware','cowboy_quicer','cowboy_req','cowboy_rest','cowboy_router','cowboy_static','cowboy_stream','cowboy_stream_h','cowboy_sub_protocol','cowboy_sup','cowboy_tls','cowboy_tracer_h','cowboy_websocket']},
+	{modules, ['cowboy','cowboy_app','cowboy_bstr','cowboy_children','cowboy_clear','cowboy_clock','cowboy_compress_h','cowboy_constraints','cowboy_decompress_h','cowboy_handler','cowboy_http','cowboy_http2','cowboy_http3','cowboy_loop','cowboy_metrics_h','cowboy_middleware','cowboy_quicer','cowboy_req','cowboy_rest','cowboy_router','cowboy_static','cowboy_stream','cowboy_stream_h','cowboy_sub_protocol','cowboy_sup','cowboy_tls','cowboy_tracer_h','cowboy_websocket','cowboy_webtransport']},
 	{registered, [cowboy_sup,cowboy_clock]},
 	{applications, [kernel,stdlib,crypto,cowlib,ranch]},
 	{optional_applications, []},
--- a/src/cowboy.erl
+++ b/src/cowboy.erl
@ -95,8 +95,14 @@ start_quic(Ref, TransOpts, ProtoOpts) ->
 	end,
 	SocketOpts = [
 		{alpn, ["h3"]}, %% @todo Why not binary?
-		{peer_unidi_stream_count, 3}, %% We only need control and QPACK enc/dec.
-		{peer_bidi_stream_count, 100}
+		%% We only need 3 for control and QPACK enc/dec,
+		%% but we need more for WebTransport. %% @todo Use 3 if WT is disabled.
+		{peer_unidi_stream_count, 100},
+		{peer_bidi_stream_count, 100},
+		%% For WebTransport.
+		%% @todo We probably don't want it enabled if WT isn't used.
+		{datagram_send_enabled, 1},
+		{datagram_receive_enabled, 1}
 	|SocketOpts2],
 	_ListenerPid = spawn(fun() ->
 		{ok, Listener} = quicer:listen(Port, SocketOpts),
--- a/src/cowboy_http3.erl
+++ b/src/cowboy_http3.erl
@ -32,10 +32,10 @@
 	enable_connect_protocol => boolean(),
 	env => cowboy_middleware:env(),
 	logger => module(),
-    max_decode_blocked_streams => 0..16#3fffffffffffffff,
-    max_decode_table_size => 0..16#3fffffffffffffff,
-    max_encode_blocked_streams => 0..16#3fffffffffffffff,
-    max_encode_table_size => 0..16#3fffffffffffffff,
+	max_decode_blocked_streams => 0..16#3fffffffffffffff,
+	max_decode_table_size => 0..16#3fffffffffffffff,
+	max_encode_blocked_streams => 0..16#3fffffffffffffff,
+	max_encode_table_size => 0..16#3fffffffffffffff,
 	max_ignored_frame_size_received => non_neg_integer() | infinity,
 	metrics_callback => cowboy_metrics_h:metrics_callback(),
 	metrics_req_filter => fun((cowboy_req:req()) -> map()),
@ -51,18 +51,30 @@
 }.
 -export_type([opts/0]).

+%% HTTP/3 or WebTransport stream.
+%%
+%% WebTransport sessions involve one bidirectional CONNECT stream
+%% that must stay open (and can be used for signaling using the
+%% Capsule Protocol) and an application-defined number of
+%% unidirectional and bidirectional streams, as well as datagrams.
+%%
+%% WebTransport sessions run in the CONNECT request process and
+%% all events related to the session is sent there as a message.
+%% The pid of the process is kept in the state.
 -record(stream, {
 	id :: cow_http3:stream_id(),

 	%% Whether the stream is currently in a special state.
 	status :: header | {unidi, control | encoder | decoder}
-		| normal | {data | ignore, non_neg_integer()} | stopping,
+		| normal | {data | ignore, non_neg_integer()} | stopping
+		| {webtransport_session, normal | {ignore, non_neg_integer()}}
+		| {webtransport_stream, cow_http3:stream_id()},

 	%% Stream buffer.
 	buffer = <<>> :: binary(),

 	%% Stream state.
-	state = undefined :: undefined | {module, any()}
+	state = undefined :: undefined | {module(), any()}
 }).

 -record(state, {
@ -152,6 +164,9 @@ loop(State0=#state{opts=Opts, children=Children}) ->
 		%% Messages pertaining to a stream.
 		{{Pid, StreamID}, Msg} when Pid =:= self() ->
 			loop(info(State0, StreamID, Msg));
+		%% WebTransport commands.
+		{'$webtransport_commands', SessionID, Commands} ->
+			loop(webtransport_commands(State0, SessionID, Commands));
 		%% Exit signal from children.
 		Msg = {'EXIT', Pid, _} ->
 			loop(down(State0, Pid, Msg));
@ -164,12 +179,17 @@ handle_quic_msg(State0=#state{opts=Opts}, Msg) ->
 	case cowboy_quicer:handle(Msg) of
 		{data, StreamID, IsFin, Data} ->
 			parse(State0, StreamID, Data, IsFin);
+		{datagram, Data} ->
+			parse_datagram(State0, Data);
 		{stream_started, StreamID, StreamType} ->
 			State = stream_new_remote(State0, StreamID, StreamType),
 			loop(State);
 		{stream_closed, StreamID, ErrorCode} ->
 			State = stream_closed(State0, StreamID, ErrorCode),
 			loop(State);
+		{peer_send_shutdown, StreamID} ->
+			State = stream_peer_send_shutdown(State0, StreamID),
+			loop(State);
 		closed ->
 			%% @todo Different error reason if graceful?
 			Reason = {socket_error, closed, 'The socket has been closed.'},
@ -216,6 +236,56 @@ parse1(State=#state{http3_machine=HTTP3Machine0},
 		{error, Error={connection_error, _, _}, HTTP3Machine} ->
 			terminate(State#state{http3_machine=HTTP3Machine}, Error)
 	end;
+%% @todo Handle when IsFin = fin which must terminate the WT session.
+parse1(State=#state{conn=Conn}, Stream=#stream{id=SessionID, status=
+		{webtransport_session, normal}}, Data, IsFin) ->
+	case cow_capsule:parse(Data) of
+		{ok, wt_drain_session, Rest} ->
+			webtransport_event(State, SessionID, close_initiated),
+			parse1(State, Stream, Rest, IsFin);
+		{ok, {wt_close_session, AppCode, AppMsg}, Rest} ->
+			%% This event will be handled specially and lead
+			%% to the termination of the session process.
+			webtransport_event(State, SessionID, {closed, AppCode, AppMsg}),
+			%% Shutdown the CONNECT stream immediately.
+			cowboy_quicer:shutdown_stream(Conn, SessionID),
+			%% @todo Will we receive a {stream_closed,...} after that?
+			%% If any data is received past that point this is an error.
+			%% @todo Don't crash, error out properly.
+			<<>> = Rest,
+			loop(webtransport_terminate_session(State, Stream));
+		more ->
+			loop(stream_store(State, Stream#stream{buffer=Data}));
+		%% Ignore unhandled/unknown capsules.
+		%% @todo Do this when cow_capsule includes some.
+%		{ok, _, Rest} ->
+%			parse1(State, Stream, Rest, IsFin);
+%		{ok, Rest} ->
+%			parse1(State, Stream, Rest, IsFin);
+		%% @todo Make the max length configurable?
+		{skip, Len} when Len =< 8192 ->
+			loop(stream_store(State, Stream#stream{
+				status={webtransport_session, {ignore, Len}}}));
+		{skip, Len} ->
+			%% @todo What should be done on capsule error?
+			error({todo, capsule_too_long, Len});
+		error ->
+			%% @todo What should be done on capsule error?
+			error({todo, capsule_error, Data})
+	end;
+parse1(State, Stream=#stream{status=
+		{webtransport_session, {ignore, Len}}}, Data, IsFin) ->
+	case Data of
+		<<_:Len/unit:8, Rest/bits>> ->
+			parse1(State, Stream#stream{status={webtransport_session, normal}}, Rest, IsFin);
+		_ ->
+			loop(stream_store(State, Stream#stream{
+				status={webtransport_session, {ignore, Len - byte_size(Data)}}}))
+	end;
+parse1(State, #stream{id=StreamID, status={webtransport_stream, SessionID}}, Data, IsFin) ->
+	webtransport_event(State, SessionID, {stream_data, StreamID, IsFin, Data}),
+	%% No need to store the stream again, WT streams don't get changed here.
+	loop(State);
 parse1(State, Stream=#stream{status={data, Len}, id=StreamID}, Data, IsFin) ->
 	DataLen = byte_size(Data),
 	if
@ -246,6 +316,9 @@ parse1(State=#state{opts=Opts}, Stream=#stream{id=StreamID}, Data, IsFin) ->
 		{ok, Frame, Rest} ->
 			FrameIsFin = is_fin(IsFin, Rest),
 			parse(frame(State, Stream, Frame, FrameIsFin), StreamID, Rest, IsFin);
+		%% The WebTransport stream header is not a real frame.
+		{webtransport_stream_header, SessionID, Rest} ->
+			become_webtransport_stream(State, Stream, bidi, SessionID, Rest, IsFin);
 		{more, Frame = {data, _}, Len} ->
 			%% We're at the end of the data so FrameIsFin is equivalent to IsFin.
 			case IsFin of
@ -317,13 +390,24 @@ parse_unidirectional_stream_header(State0=#state{http3_machine=HTTP3Machine0},
 				{error, Error={connection_error, _, _}, HTTP3Machine} ->
 					terminate(State0#state{http3_machine=HTTP3Machine}, Error)
 			end;
+		%% @todo Perhaps do this in cow_http3_machine directly.
 		{ok, push, _} ->
 			terminate(State0, {connection_error, h3_stream_creation_error,
 				'Only servers can push. (RFC9114 6.2.2)'});
+		{ok, {webtransport, SessionID}, Rest} ->
+			become_webtransport_stream(State0, Stream0, unidi, SessionID, Rest, IsFin);
 		%% Unknown stream types must be ignored. We choose to abort the
 		%% stream instead of reading and discarding the incoming data.
 		{undefined, _} ->
-			loop(stream_abort_receive(State0, Stream0, h3_stream_creation_error))
+			loop(stream_abort_receive(State0, Stream0, h3_stream_creation_error));
+		%% Very unlikely to happen but WebTransport headers may be fragmented
+		%% as they are more than one byte. The fin flag in this case is an error,
+		%% but because it happens in WebTransport application data (the Session ID)
+		%% we only reset the impacted stream and not the entire connection.
+		more when IsFin =:= fin ->
+			loop(stream_abort_receive(State0, Stream0, h3_stream_creation_error));
+		more ->
+			loop(stream_store(State0, Stream0#stream{buffer=Data}))
 	end.

 frame(State=#state{http3_machine=HTTP3Machine0},
@ -449,6 +533,8 @@ headers_to_map([{Name, Value}|Tail], Acc0) ->
 	end,
 	headers_to_map(Tail, Acc).

+%% @todo WebTransport CONNECT requests must have extra checks on settings.
+%% @todo We may also need to defer them if we didn't get settings.
 headers_frame(State=#state{opts=Opts}, Stream=#stream{id=StreamID}, Req) ->
 	try cowboy_stream:init(StreamID, Req, Opts) of
 		{Commands, StreamState} ->
@ -488,6 +574,18 @@ early_error(State0=#state{ref=Ref, opts=Opts, peer=Peer},
 		send_headers(State0, Stream, fin, StatusCode0, RespHeaders0)
 	end.

+%% Datagrams.
+
+parse_datagram(State, Data0) ->
+	{SessionID, Data} = cow_http3:parse_datagram(Data0),
+	case stream_get(State, SessionID) of
+		#stream{status={webtransport_session, _}} ->
+			webtransport_event(State, SessionID, {datagram, Data}),
+			loop(State);
+		_ ->
+			error(todo) %% @todo Might be a future WT session or an error.
+	end.
+
 %% Erlang messages.

 down(State0=#state{opts=Opts, children=Children0}, Pid, Msg) ->
@ -653,6 +751,22 @@ commands(State, Stream, [Error = {internal_error, _, _}|_Tail]) ->
 	reset_stream(State, Stream, Error);
 %% Use a different protocol within the stream (CONNECT :protocol).
 %% @todo Make sure we error out when the feature is disabled.
+commands(State0, Stream0=#stream{id=StreamID},
+		[{switch_protocol, Headers, cowboy_webtransport, WTState=#{}}|Tail]) ->
+	State = info(stream_store(State0, Stream0), StreamID, {headers, 200, Headers}),
+	#state{http3_machine=HTTP3Machine0} = State,
+	Stream1 = #stream{state=StreamState} = stream_get(State, StreamID),
+	%% The stream becomes a WT session at that point. It is the
+	%% parent stream of all streams in this WT session. The
+	%% cowboy_stream state is kept because it will be needed
+	%% to terminate the stream properly.
+	HTTP3Machine = cow_http3_machine:become_webtransport_session(StreamID, HTTP3Machine0),
+	Stream = Stream1#stream{
+		status={webtransport_session, normal},
+		state={cowboy_webtransport, WTState#{stream_state => StreamState}}
+	},
+	%% @todo We must propagate the buffer to capsule handling if any.
+	commands(State#state{http3_machine=HTTP3Machine}, Stream, Tail);
 commands(State0, Stream0=#stream{id=StreamID},
 		[{switch_protocol, Headers, _Mod, _ModState}|Tail]) ->
 	State = info(stream_store(State0, Stream0), StreamID, {headers, 200, Headers}),
@ -758,6 +872,158 @@ send_instructions(State=#state{conn=Conn, local_encoder_id=EncoderID},
 		cowboy_quicer:send(Conn, EncoderID, EncData)),
 	State.

+%% We mark the stream as being a WebTransport stream
+%% and then continue parsing the data as a WebTransport
+%% stream. This function is common for incoming unidi
+%% and bidi streams.
+become_webtransport_stream(State0=#state{http3_machine=HTTP3Machine0},
+		Stream0=#stream{id=StreamID}, StreamType, SessionID, Rest, IsFin) ->
+	case cow_http3_machine:become_webtransport_stream(StreamID, SessionID, HTTP3Machine0) of
+		{ok, HTTP3Machine} ->
+			State = State0#state{http3_machine=HTTP3Machine},
+			Stream = Stream0#stream{status={webtransport_stream, SessionID}},
+			webtransport_event(State, SessionID, {stream_open, StreamID, StreamType}),
+			%% We don't need to parse the remaining data if there isn't any.
+			case {Rest, IsFin} of
+				{<<>>, nofin} -> loop(stream_store(State, Stream));
+				_ -> parse(stream_store(State, Stream), StreamID, Rest, IsFin)
+			end
+		%% @todo Error conditions.
+	end.
+
+webtransport_event(State, SessionID, Event) ->
+	#stream{
+		status={webtransport_session, _},
+		state={cowboy_webtransport, #{session_pid := SessionPid}}
+	} = stream_get(State, SessionID),
+	SessionPid ! {'$webtransport_event', SessionID, Event},
+	ok.
+
+webtransport_commands(State, SessionID, Commands) ->
+	case stream_get(State, SessionID) of
+		Session = #stream{status={webtransport_session, _}} ->
+			wt_commands(State, Session, Commands);
+		%% The stream has been terminated, ignore pending commands.
+		error ->
+			State
+	end.
+
+wt_commands(State, _, []) ->
+	State;
+wt_commands(State0=#state{conn=Conn}, Session=#stream{id=SessionID},
+		[{open_stream, OpenStreamRef, StreamType, InitialData}|Tail]) ->
+	%% Because opening the stream involves sending a short header
+	%% we necessarily write data. The InitialData variable allows
+	%% providing additional data to be sent in the same packet.
+	StartF = case StreamType of
+		bidi -> start_bidi_stream;
+		unidi -> start_unidi_stream
+	end,
+	Header = cow_http3:webtransport_stream_header(SessionID, StreamType),
+	case cowboy_quicer:StartF(Conn, [Header, InitialData]) of
+		{ok, StreamID} ->
+			%% @todo Pass Session directly?
+			webtransport_event(State0, SessionID,
+				{opened_stream_id, OpenStreamRef, StreamID}),
+			State = stream_new_local(State0, StreamID, StreamType,
+				{webtransport_stream, SessionID}),
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end;
+wt_commands(State, Session, [{close_stream, StreamID, Code}|Tail]) ->
+	%% @todo Check that StreamID belongs to Session.
+	error({todo, State, Session, [{close_stream, StreamID, Code}|Tail]});
+wt_commands(State=#state{conn=Conn}, Session=#stream{id=SessionID},
+		[{send, datagram, Data}|Tail]) ->
+	case cowboy_quicer:send_datagram(Conn, cow_http3:datagram(SessionID, Data)) of
+		ok ->
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end;
+wt_commands(State=#state{conn=Conn}, Session, [{send, StreamID, Data}|Tail]) ->
+	%% @todo Check that StreamID belongs to Session.
+	case cowboy_quicer:send(Conn, StreamID, Data, nofin) of
+		ok ->
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end;
+wt_commands(State=#state{conn=Conn}, Session, [{send, StreamID, IsFin, Data}|Tail]) ->
+	%% @todo Check that StreamID belongs to Session.
+	case cowboy_quicer:send(Conn, StreamID, Data, IsFin) of
+		ok ->
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end;
+wt_commands(State=#state{conn=Conn}, Session=#stream{id=SessionID}, [initiate_close|Tail]) ->
+	%% We must send a WT_DRAIN_SESSION capsule on the CONNECT stream.
+	Capsule = cow_capsule:wt_drain_session(),
+	case cowboy_quicer:send(Conn, SessionID, Capsule, nofin) of
+		ok ->
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end;
+wt_commands(State0=#state{conn=Conn}, Session=#stream{id=SessionID}, [Cmd|Tail])
+		when Cmd =:= close; element(1, Cmd) =:= close ->
+	%% We must send a WT_CLOSE_SESSION capsule on the CONNECT stream.
+	{AppCode, AppMsg} = case Cmd of
+		close -> {0, <<>>};
+		{close, AppCode0} -> {AppCode0, <<>>};
+		{close, AppCode0, AppMsg0} -> {AppCode0, AppMsg0}
+	end,
+	Capsule = cow_capsule:wt_close_session(AppCode, AppMsg),
+	case cowboy_quicer:send(Conn, SessionID, Capsule, fin) of
+		ok ->
+			%% @todo The endpoint MAY send a STOP_SENDING to indicate it is no longer reading from the CONNECT stream.
+			State = webtransport_terminate_session(State0, Session),
+			%% @todo Because the handler is in a separate process
+			%%       we must wait for it to stop and eventually
+			%%       kill the process if it takes too long.
+			%% @todo We may need to fully close the CONNECT stream (if remote doesn't reset it).
+			wt_commands(State, Session, Tail)
+		%% @todo Handle errors.
+	end.
+
+webtransport_terminate_session(State=#state{conn=Conn, http3_machine=HTTP3Machine0,
+		streams=Streams0, lingering_streams=Lingering0}, #stream{id=SessionID}) ->
+	%% Reset/abort the WT streams.
+	Streams = maps:filtermap(fun
+		(_, #stream{id=StreamID, status={webtransport_session, _}})
+				when StreamID =:= SessionID ->
+			%% We remove the session stream but do the shutdown outside this function.
+			false;
+		(StreamID, #stream{status={webtransport_stream, StreamSessionID}})
+				when StreamSessionID =:= SessionID ->
+			cowboy_quicer:shutdown_stream(Conn, StreamID,
+				both, cow_http3:error_to_code(webtransport_session_gone)),
+			false;
+		(_, _) ->
+			true
+	end, Streams0),
+	%% Keep the streams in lingering state.
+	%% We only keep up to 100 streams in this state. @todo Make it configurable?
+	Terminated = maps:keys(Streams0) -- maps:keys(Streams),
+	Lingering = lists:sublist(Terminated ++ Lingering0, 100),
+	%% Update the HTTP3 state machine.
+	HTTP3Machine = cow_http3_machine:close_webtransport_session(SessionID, HTTP3Machine0),
+	State#state{
+		http3_machine=HTTP3Machine,
+		streams=Streams,
+		lingering_streams=Lingering
+	}.
+
+stream_peer_send_shutdown(State=#state{conn=Conn}, StreamID) ->
+	case stream_get(State, StreamID) of
+		%% Cleanly terminating the CONNECT stream is equivalent
+		%% to an application error code of 0 and empty message.
+		Stream = #stream{status={webtransport_session, _}} ->
+			webtransport_event(State, StreamID, {closed, 0, <<>>}),
+			%% Shutdown the CONNECT stream fully.
+			cowboy_quicer:shutdown_stream(Conn, StreamID),
+			webtransport_terminate_session(State, Stream);
+		_ ->
+			State
+	end.
+
 reset_stream(State0=#state{conn=Conn, http3_machine=HTTP3Machine0},
 		Stream=#stream{id=StreamID}, Error) ->
 	Reason = case Error of
@ -903,15 +1169,25 @@ terminate_all_streams(State, [{StreamID, #stream{state=StreamState}}|Tail], Reas
 stream_get(#state{streams=Streams}, StreamID) ->
 	maps:get(StreamID, Streams, error).

-stream_new_remote(State=#state{http3_machine=HTTP3Machine0, streams=Streams},
-		StreamID, StreamType) ->
+stream_new_local(State, StreamID, StreamType, Status) ->
+	stream_new(State, StreamID, StreamType, unidi_local, Status).
+
+stream_new_remote(State, StreamID, StreamType) ->
+	Status = case StreamType of
+		unidi -> header;
+		bidi -> normal
+	end,
+	stream_new(State, StreamID, StreamType, unidi_remote, Status).
+
+stream_new(State=#state{http3_machine=HTTP3Machine0, streams=Streams},
+		StreamID, StreamType, UnidiType, Status) ->
 	{HTTP3Machine, Status} = case StreamType of
 		unidi ->
-			{cow_http3_machine:init_unidi_stream(StreamID, unidi_remote, HTTP3Machine0),
-				header};
+			{cow_http3_machine:init_unidi_stream(StreamID, UnidiType, HTTP3Machine0),
+				Status};
 		bidi ->
 			{cow_http3_machine:init_bidi_stream(StreamID, HTTP3Machine0),
-				normal}
+				Status}
 	end,
 	Stream = #stream{id=StreamID, status=Status},
 	State#state{http3_machine=HTTP3Machine, streams=Streams#{StreamID => Stream}}.
@ -926,6 +1202,11 @@ stream_closed(State=#state{local_decoder_id=StreamID}, StreamID, _) ->
 stream_closed(State=#state{opts=Opts,
 		streams=Streams0, children=Children0}, StreamID, ErrorCode) ->
 	case maps:take(StreamID, Streams0) of
+		%% In the WT session's case, streams will be
+		%% removed in webtransport_terminate_session.
+		{Stream=#stream{status={webtransport_session, _}}, _} ->
+			webtransport_event(State, StreamID, closed_abruptly),
+			webtransport_terminate_session(State, Stream);
 		{#stream{state=undefined}, Streams} ->
 			%% Unidi stream has no handler/children.
 			stream_closed1(State#state{streams=Streams}, StreamID);
--- a/src/cowboy_quicer.erl
+++ b/src/cowboy_quicer.erl
@ -23,9 +23,12 @@
 -export([shutdown/2]).

 %% Streams.
+-export([start_bidi_stream/2]).
 -export([start_unidi_stream/2]).
 -export([send/3]).
 -export([send/4]).
+-export([send_datagram/2]).
+-export([shutdown_stream/2]).
 -export([shutdown_stream/4]).

 %% Messages.
@ -45,6 +48,9 @@ peercert(_) -> no_quicer().
 -spec shutdown(_, _) -> no_return().
 shutdown(_, _) -> no_quicer().

+-spec start_bidi_stream(_, _) -> no_return().
+start_bidi_stream(_, _) -> no_quicer().
+
 -spec start_unidi_stream(_, _) -> no_return().
 start_unidi_stream(_, _) -> no_quicer().

@ -54,6 +60,12 @@ send(_, _, _) -> no_quicer().
 -spec send(_, _, _, _) -> no_return().
 send(_, _, _, _) -> no_quicer().

+-spec send_datagram(_, _) -> no_return().
+send_datagram(_, _) -> no_quicer().
+
+-spec shutdown_stream(_, _) -> no_return().
+shutdown_stream(_, _) -> no_quicer().
+
 -spec shutdown_stream(_, _, _, _) -> no_return().
 shutdown_stream(_, _, _, _) -> no_quicer().

@ -109,16 +121,26 @@ shutdown(Conn, ErrorCode) ->

 %% Streams.

+-spec start_bidi_stream(quicer_connection_handle(), iodata())
+	-> {ok, cow_http3:stream_id()}
+	| {error, any()}.
+
+start_bidi_stream(Conn, InitialData) ->
+	start_stream(Conn, InitialData, ?QUIC_STREAM_OPEN_FLAG_NONE).
+
 -spec start_unidi_stream(quicer_connection_handle(), iodata())
 	-> {ok, cow_http3:stream_id()}
 	| {error, any()}.

-start_unidi_stream(Conn, HeaderData) ->
+start_unidi_stream(Conn, InitialData) ->
+	start_stream(Conn, InitialData, ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL).
+
+start_stream(Conn, InitialData, OpenFlag) ->
 	case quicer:start_stream(Conn, #{
 			active => true,
-			open_flag => ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL}) of
+			open_flag => OpenFlag}) of
 		{ok, StreamRef} ->
-			case quicer:send(StreamRef, HeaderData) of
+			case quicer:send(StreamRef, InitialData) of
 				{ok, _} ->
 					{ok, StreamID} = quicer:get_stream_id(StreamRef),
 					put({quicer_stream, StreamID}, StreamRef),
@ -156,6 +178,29 @@ send(_Conn, StreamID, Data, IsFin) ->
 send_flag(nofin) -> ?QUIC_SEND_FLAG_NONE;
 send_flag(fin) -> ?QUIC_SEND_FLAG_FIN.

+-spec send_datagram(quicer_connection_handle(), iodata())
+	-> ok | {error, any()}.
+
+send_datagram(Conn, Data) ->
+	%% @todo Fix/ignore the Dialyzer error instead of doing this.
+	DataBin = iolist_to_binary(Data),
+	Size = byte_size(DataBin),
+	case quicer:send_dgram(Conn, DataBin) of
+		{ok, Size} ->
+			ok;
+		%% @todo Handle error cases.
+		Error ->
+			Error
+	end.
+
+-spec shutdown_stream(quicer_connection_handle(), cow_http3:stream_id())
+	-> ok.
+
+shutdown_stream(_Conn, StreamID) ->
+	StreamRef = get({quicer_stream, StreamID}),
+	_ = quicer:shutdown_stream(StreamRef),
+	ok.
+
 -spec shutdown_stream(quicer_connection_handle(),
 	cow_http3:stream_id(), both | receiving, quicer_app_errno())
 	-> ok.
@ -165,6 +210,7 @@ shutdown_stream(_Conn, StreamID, Dir, ErrorCode) ->
 	_ = quicer:shutdown_stream(StreamRef, shutdown_flag(Dir), ErrorCode, infinity),
 	ok.

+%% @todo Are these flags correct for what we want?
 shutdown_flag(both) -> ?QUIC_STREAM_SHUTDOWN_FLAG_ABORT;
 shutdown_flag(receiving) -> ?QUIC_STREAM_SHUTDOWN_FLAG_ABORT_RECEIVE.

@ -173,9 +219,11 @@ shutdown_flag(receiving) -> ?QUIC_STREAM_SHUTDOWN_FLAG_ABORT_RECEIVE.
 %% @todo Probably should have the Conn given as argument too?
 -spec handle({quic, _, _, _})
 	-> {data, cow_http3:stream_id(), cow_http:fin(), binary()}
+	| {datagram, binary()}
 	| {stream_started, cow_http3:stream_id(), unidi | bidi}
 	| {stream_closed, cow_http3:stream_id(), quicer_app_errno()}
 	| closed
+	| {peer_send_shutdown, cow_http3:stream_id()}
 	| ok
 	| unknown
 	| {socket_error, any()}.
@ -187,6 +235,9 @@ handle({quic, Data, StreamRef, #{flags := Flags}}) when is_binary(Data) ->
 		_ -> nofin
 	end,
 	{data, StreamID, IsFin, Data};
+%% @todo Match on Conn.
+handle({quic, Data, _Conn, Flags}) when is_binary(Data), is_integer(Flags) ->
+	{datagram, Data};
 %% QUIC_CONNECTION_EVENT_PEER_STREAM_STARTED.
 handle({quic, new_stream, StreamRef, #{flags := Flags}}) ->
 	case quicer:setopt(StreamRef, active, true) of
@ -219,8 +270,9 @@ handle({quic, dgram_state_changed, _Conn, _Props}) ->
 %% QUIC_CONNECTION_EVENT_SHUTDOWN_INITIATED_BY_TRANSPORT
 handle({quic, transport_shutdown, _Conn, _Flags}) ->
 	ok;
-handle({quic, peer_send_shutdown, _StreamRef, undefined}) ->
-	ok;
+handle({quic, peer_send_shutdown, StreamRef, undefined}) ->
+	{ok, StreamID} = quicer:get_stream_id(StreamRef),
+	{peer_send_shutdown, StreamID};
 handle({quic, send_shutdown_complete, _StreamRef, _IsGraceful}) ->
 	ok;
 handle({quic, shutdown, _Conn, success}) ->
--- a/src/cowboy_req.erl
+++ b/src/cowboy_req.erl
@ -445,6 +445,7 @@ parse_header_fun(<<"sec-websocket-protocol">>) -> fun cow_http_hd:parse_sec_webs
 parse_header_fun(<<"sec-websocket-version">>) -> fun cow_http_hd:parse_sec_websocket_version_req/1;
 parse_header_fun(<<"trailer">>) -> fun cow_http_hd:parse_trailer/1;
 parse_header_fun(<<"upgrade">>) -> fun cow_http_hd:parse_upgrade/1;
+parse_header_fun(<<"wt-available-protocols">>) -> fun cow_http_hd:parse_wt_available_protocols/1;
 parse_header_fun(<<"x-forwarded-for">>) -> fun cow_http_hd:parse_x_forwarded_for/1.

 parse_header(Name, Req, Default, ParseFun) ->
--- a/src/cowboy_rest.erl
+++ b/src/cowboy_rest.erl
@ -1622,5 +1622,6 @@ error_terminate(Req, #state{handler=Handler, handler_state=HandlerState}, Class,
 	erlang:raise(Class, Reason, Stacktrace).

 terminate(Req, #state{handler=Handler, handler_state=HandlerState}) ->
+	%% @todo I don't think the result is used anywhere?
 	Result = cowboy_handler:terminate(normal, Req, HandlerState, Handler),
 	{ok, Req, Result}.
--- a/src/cowboy_stream.erl
+++ b/src/cowboy_stream.erl
@ -49,6 +49,7 @@
 -type reason() :: normal | switch_protocol
 	| {internal_error, timeout | {error | exit | throw, any()}, human_reason()}
 	| {socket_error, closed | atom(), human_reason()}
+	%% @todo Or cow_http3:error().
 	| {stream_error, cow_http2:error(), human_reason()}
 	| {connection_error, cow_http2:error(), human_reason()}
 	| {stop, cow_http2:frame() | {exit, any()}, human_reason()}.
--- a/src/cowboy_websocket.erl
+++ b/src/cowboy_websocket.erl
@ -402,6 +402,7 @@ before_loop(State, HandlerState, ParseState) ->

 -spec set_idle_timeout(#state{}, 0..?IDLE_TIMEOUT_TICKS) -> #state{}.

+%% @todo Do we really need this for HTTP/2?
 set_idle_timeout(State=#state{opts=Opts, timeout_ref=PrevRef}, TimeoutNum) ->
 	%% Most of the time we don't need to cancel the timer since it
 	%% will have triggered already. But this call is harmless so
--- a/src/cowboy_webtransport.erl
+++ b/src/cowboy_webtransport.erl
@ -0,0 +1,292 @@
+%% Copyright (c) Loïc Hoguin <essen@ninenines.eu>
+%%
+%% Permission to use, copy, modify, and/or distribute this software for any
+%% purpose with or without fee is hereby granted, provided that the above
+%% copyright notice and this permission notice appear in all copies.
+%%
+%% THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+%% WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+%% MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+%% ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+%% WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+%% ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+%% OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+%% @todo To enable WebTransport the following options need to be set:
+%%
+%% QUIC:
+%%  - max_datagram_frame_size > 0
+%%
+%% HTTP/3:
+%%  - SETTINGS_H3_DATAGRAM = 1
+%%  - SETTINGS_ENABLE_CONNECT_PROTOCOL = 1
+%%  - SETTINGS_WEBTRANSPORT_MAX_SESSIONS >= 1
+
+%% Cowboy supports versions 07 through 13 of the WebTransport drafts.
+%% Cowboy also has some compatibility with version 02.
+%%
+%% WebTransport CONNECT requests go through cowboy_stream as normal
+%% and then an upgrade/switch_protocol is issued (just like Websocket).
+%% After that point none of the events go through cowboy_stream except
+%% the final terminate event. The request process becomes the process
+%% handling all events in the WebTransport session.
+%%
+%% WebTransport sessions can be ended via a command, via a crash or
+%% exit, via the closing of the connection (client or server inititated),
+%% via the client ending the session (mirroring the command) or via
+%% the client terminating the CONNECT stream.
+-module(cowboy_webtransport).
+
+-export([upgrade/4]).
+-export([upgrade/5]).
+
+%% cowboy_stream.
+-export([info/3]).
+-export([terminate/3]).
+
+-type stream_type() :: unidi | bidi.
+-type open_stream_ref() :: any().
+
+-type event() ::
+	{stream_open, cow_http3:stream_id(), stream_type()} |
+	{opened_stream_id, open_stream_ref(), cow_http3:stream_id()} |
+	{stream_data, cow_http3:stream_id(), cow_http:fin(), binary()} |
+	{datagram, binary()} |
+	close_initiated.
+
+-type commands() :: [
+	{open_stream, open_stream_ref(), stream_type(), iodata()} |
+	{close_stream, cow_http3:stream_id(), cow_http3:wt_app_error_code()} |
+	{send, cow_http3:stream_id() | datagram, iodata()} |
+	initiate_close |
+	close |
+	{close, cow_http3:wt_app_error_code()} |
+	{close, cow_http3:wt_app_error_code(), iodata()}
+].
+-export_type([commands/0]).
+
+-type call_result(State) :: {commands(), State} | {commands(), State, hibernate}.
+
+-callback init(Req, any())
+	-> {ok | module(), Req, any()}
+	| {module(), Req, any(), any()}
+	when Req::cowboy_req:req().
+
+-callback webtransport_init(State)
+	-> call_result(State) when State::any().
+-optional_callbacks([webtransport_init/1]).
+
+-callback webtransport_handle(event(), State)
+	-> call_result(State) when State::any().
+-optional_callbacks([webtransport_handle/2]).
+
+-callback webtransport_info(any(), State)
+	-> call_result(State) when State::any().
+-optional_callbacks([webtransport_info/2]).
+
+-callback terminate(any(), cowboy_req:req(), any()) -> ok.
+-optional_callbacks([terminate/3]).
+
+-type opts() :: #{
+	req_filter => fun((cowboy_req:req()) -> map())
+}.
+-export_type([opts/0]).
+
+-record(state, {
+	id :: cow_http3:stream_id(),
+	parent :: pid(),
+	opts = #{} :: opts(),
+	handler :: module(),
+	hibernate = false :: boolean(),
+	req = #{} :: map()
+}).
+
+%% This function mirrors a similar function for Websocket.
+
+-spec is_upgrade_request(cowboy_req:req()) -> boolean().
+
+is_upgrade_request(#{version := Version, method := <<"CONNECT">>, protocol := Protocol})
+		when Version =:= 'HTTP/3' ->
+	%% @todo scheme MUST BE "https"
+	<<"webtransport">> =:= cowboy_bstr:to_lower(Protocol);
+
+is_upgrade_request(_) ->
+	false.
+
+%% Stream process.
+
+-spec upgrade(Req, Env, module(), any())
+	-> {ok, Req, Env}
+	when Req::cowboy_req:req(), Env::cowboy_middleware:env().
+
+upgrade(Req, Env, Handler, HandlerState) ->
+	upgrade(Req, Env, Handler, HandlerState, #{}).
+
+-spec upgrade(Req, Env, module(), any(), opts())
+	-> {ok, Req, Env}
+	when Req::cowboy_req:req(), Env::cowboy_middleware:env().
+
+%% @todo Immediately crash if a response has already been sent.
+upgrade(Req=#{version := 'HTTP/3', pid := Pid, streamid := StreamID}, Env, Handler, HandlerState, Opts) ->
+	FilteredReq = case maps:get(req_filter, Opts, undefined) of
+		undefined -> maps:with([method, version, scheme, host, port, path, qs, peer], Req);
+		FilterFun -> FilterFun(Req)
+	end,
+	State = #state{id=StreamID, parent=Pid, opts=Opts, handler=Handler, req=FilteredReq},
+	%% @todo Must ensure the relevant settings are enabled (QUIC and H3).
+	%% Either we check them BEFORE, or we check them when the handler
+	%% is OK to initiate a webtransport session. Probably need to
+	%% check them BEFORE as we need to become (takeover) the webtransport process
+	%% after we are done with the upgrade. Maybe in cow_http3_machine but
+	%% it doesn't have QUIC settings currently (max_datagram_size).
+	case is_upgrade_request(Req) of
+		true ->
+			Headers = cowboy_req:response_headers(#{}, Req),
+			Pid ! {{Pid, StreamID}, {switch_protocol, Headers, ?MODULE,
+				#{session_pid => self()}}},
+			webtransport_init(State, HandlerState);
+		%% Use 501 Not Implemented to mirror the recommendation in
+		%% by RFC9220 3 (WebSockets Upgrade over HTTP/3).
+		false ->
+			%% @todo I don't think terminate will be called.
+			{ok, cowboy_req:reply(501, Req), Env}
+	end.
+
+webtransport_init(State=#state{handler=Handler}, HandlerState) ->
+	case erlang:function_exported(Handler, webtransport_init, 1) of
+		true -> handler_call(State, HandlerState, webtransport_init, undefined);
+		false -> before_loop(State, HandlerState)
+	end.
+
+before_loop(State=#state{hibernate=true}, HandlerState) ->
+	proc_lib:hibernate(?MODULE, loop, [State#state{hibernate=false}, HandlerState]);
+before_loop(State, HandlerState) ->
+	loop(State, HandlerState).
+
+-spec loop(#state{}, any()) -> no_return().
+
+loop(State=#state{id=SessionID, parent=Parent}, HandlerState) ->
+	receive
+		{'$webtransport_event', SessionID, Event={closed, _, _}} ->
+			terminate_proc(State, HandlerState, Event);
+		{'$webtransport_event', SessionID, Event=closed_abruptly} ->
+			terminate_proc(State, HandlerState, Event);
+		{'$webtransport_event', SessionID, Event} ->
+			handler_call(State, HandlerState, webtransport_handle, Event);
+		%% Timeouts.
+%% @todo idle_timeout
+%		{timeout, TRef, ?MODULE} ->
+%			tick_idle_timeout(State, HandlerState, ParseState);
+%		{timeout, OlderTRef, ?MODULE} when is_reference(OlderTRef) ->
+%			before_loop(State, HandlerState, ParseState);
+		%% System messages.
+		{'EXIT', Parent, Reason} ->
+			%% @todo We should exit gracefully.
+			exit(Reason);
+		{system, From, Request} ->
+			sys:handle_system_msg(Request, From, Parent, ?MODULE, [],
+				{State, HandlerState});
+		%% Calls from supervisor module.
+		{'$gen_call', From, Call} ->
+			cowboy_children:handle_supervisor_call(Call, From, [], ?MODULE),
+			before_loop(State, HandlerState);
+		Message ->
+			handler_call(State, HandlerState, webtransport_info, Message)
+	end.
+
+handler_call(State=#state{handler=Handler}, HandlerState, Callback, Message) ->
+	try case Callback of
+		webtransport_init -> Handler:webtransport_init(HandlerState);
+		_ -> Handler:Callback(Message, HandlerState)
+	end of
+		{Commands, HandlerState2} when is_list(Commands) ->
+			handler_call_result(State, HandlerState2, Commands);
+		{Commands, HandlerState2, hibernate} when is_list(Commands) ->
+			handler_call_result(State#state{hibernate=true}, HandlerState2, Commands)
+	catch Class:Reason:Stacktrace ->
+		%% @todo Do we need to send a close? Let cowboy_http3 detect and handle it?
+		handler_terminate(State, HandlerState, {crash, Class, Reason}),
+		erlang:raise(Class, Reason, Stacktrace)
+	end.
+
+handler_call_result(State0, HandlerState, Commands) ->
+	case commands(Commands, State0, ok, []) of
+		{ok, State} ->
+			before_loop(State, HandlerState);
+		{stop, State} ->
+			terminate_proc(State, HandlerState, stop)
+	end.
+
+%% We accumulate the commands that must be sent to the connection process
+%% because we want to send everything into one message. Other commands are
+%% processed immediately.
+
+commands([], State, Res, []) ->
+	{Res, State};
+commands([], State=#state{id=SessionID, parent=Pid}, Res, Commands) ->
+	Pid ! {'$webtransport_commands', SessionID, lists:reverse(Commands)},
+	{Res, State};
+%% {open_stream, OpenStreamRef, StreamType, InitialData}.
+commands([Command={open_stream, _, _, _}|Tail], State, Res, Acc) ->
+	commands(Tail, State, Res, [Command|Acc]);
+%% {close_stream, StreamID, Code}.
+commands([Command={close_stream, _, _}|Tail], State, Res, Acc) ->
+	commands(Tail, State, Res, [Command|Acc]);
+%% @todo We must reject send to a remote unidi stream.
+%% {send, StreamID | datagram, Data}.
+commands([Command={send, _, _}|Tail], State, Res, Acc) ->
+	commands(Tail, State, Res, [Command|Acc]);
+%% {send, StreamID, IsFin, Data}.
+commands([Command={send, _, _, _}|Tail], State, Res, Acc) ->
+	commands(Tail, State, Res, [Command|Acc]);
+%% initiate_close - DRAIN_WEBTRANSPORT_SESSION
+commands([Command=initiate_close|Tail], State, Res, Acc) ->
+	commands(Tail, State, Res, [Command|Acc]);
+%% close | {close, Code} | {close, Code, Msg} - CLOSE_WEBTRANSPORT_SESSION
+%% @todo At this point the handler must not issue stream or send commands.
+commands([Command=close|Tail], State, _, Acc) ->
+	commands(Tail, State, stop, [Command|Acc]);
+commands([Command={close, _}|Tail], State, _, Acc) ->
+	commands(Tail, State, stop, [Command|Acc]);
+commands([Command={close, _, _}|Tail], State, _, Acc) ->
+	commands(Tail, State, stop, [Command|Acc]).
+%% @todo A set_options command could be useful to increase the number of allowed streams
+%%       or other forms of flow control. Alternatively a flow command. Or both.
+%% @todo A shutdown_reason command could be useful for the same reasons as Websocekt.
+
+-spec terminate_proc(_, _, _) -> no_return().
+
+terminate_proc(State, HandlerState, Reason) ->
+	handler_terminate(State, HandlerState, Reason),
+	%% @todo This is what should be done if shutdown_reason gets implemented.
+%	case Shutdown of
+%		normal -> exit(normal);
+%		_ -> exit({shutdown, Shutdown})
+%	end.
+	exit(normal).
+
+handler_terminate(#state{handler=Handler, req=Req}, HandlerState, Reason) ->
+	cowboy_handler:terminate(Reason, Req, HandlerState, Handler).
+
+%% cowboy_stream callbacks.
+%%
+%% We shortcut stream handlers but still need to process some events
+%% such as process exiting or termination. We implement the relevant
+%% callbacks here. Note that as far as WebTransport is concerned,
+%% receiving stream data here would be an error therefore the data
+%% callback is not implemented.
+%%
+%% @todo Better type than map() for the cowboy_stream state.
+
+-spec info(cowboy_stream:streamid(), any(), State)
+	-> {cowboy_stream:commands(), State} when State::map().
+
+info(StreamID, Msg, WTState=#{stream_state := StreamState0}) ->
+	{Commands, StreamState} = cowboy_stream:info(StreamID, Msg, StreamState0),
+	{Commands, WTState#{stream_state => StreamState}}.
+
+-spec terminate(cowboy_stream:streamid(), cowboy_stream:reason(), map())
+	-> any().
+
+terminate(StreamID, Reason, #{stream_state := StreamState}) ->
+	cowboy_stream:terminate(StreamID, Reason, StreamState).
--- a/test/draft_h3_webtransport_SUITE.erl
+++ b/test/draft_h3_webtransport_SUITE.erl
@ -0,0 +1,814 @@
+%% Copyright (c) Loïc Hoguin <essen@ninenines.eu>
+%%
+%% Permission to use, copy, modify, and/or distribute this software for any
+%% purpose with or without fee is hereby granted, provided that the above
+%% copyright notice and this permission notice appear in all copies.
+%%
+%% THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
+%% WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
+%% MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
+%% ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
+%% WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
+%% ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
+%% OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
+
+-module(draft_h3_webtransport_SUITE).
+-compile(export_all).
+-compile(nowarn_export_all).
+
+-import(ct_helper, [config/2]).
+-import(ct_helper, [doc/1]).
+-import(rfc9114_SUITE, [do_wait_stream_aborted/1]).
+
+-ifdef(COWBOY_QUICER).
+
+-include_lib("quicer/include/quicer.hrl").
+
+all() ->
+	[{group, enabled}].
+
+groups() ->
+	Tests = ct_helper:all(?MODULE),
+	[{enabled, [], Tests}]. %% @todo Enable parallel when all is better.
+
+init_per_group(Name = enabled, Config) ->
+	cowboy_test:init_http3(Name, #{
+		enable_connect_protocol => true,
+		h3_datagram => true,
+		enable_webtransport => true, %% For compatibility with draft-02.
+		webtransport_max_sessions => 10,
+		env => #{dispatch => cowboy_router:compile(init_routes(Config))}
+	}, Config).
+
+end_per_group(Name, _) ->
+	cowboy_test:stop_group(Name).
+
+init_routes(_) -> [
+	{"localhost", [
+		{"/wt", wt_echo_h, []}
+	]}
+].
+
+%% Temporary.
+
+%% To start Chromium the command line is roughly:
+%% chromium --ignore-certificate-errors-spki-list=LeLykt63i2FRAm+XO91yBoSjKfrXnAFygqe5xt0zgDA= --ignore-certificate-errors --user-data-dir=/tmp/chromium-wt --allow-insecure-localhost --webtransport-developer-mode --enable-quic https://googlechrome.github.io/samples/webtransport/client.html
+%%
+%% To find the SPKI the command is roughly:
+%% openssl x509 -in ~/ninenines/cowboy/test/rfc9114_SUITE_data/server.pem -pubkey -noout | \ 
+%%  openssl pkey -pubin -outform der | \
+%%  openssl dgst -sha256 -binary | \
+%%  openssl enc -base64
+
+%run(Config) ->
+%	ct:pal("port ~p", [config(port, Config)]),
+%	timer:sleep(infinity).
+
+%% 3. Session Establishment
+
+%% 3.1. Establishing a WebTransport-Capable HTTP/3 Connection
+
+%% In order to indicate support for WebTransport, the server MUST send a SETTINGS_WEBTRANSPORT_MAX_SESSIONS value greater than "0" in its SETTINGS frame. (3.1)
+%% @todo reject_session_disabled
+%% @todo accept_session_below
+%% @todo accept_session_equal
+%% @todo reject_session_above
+
+%% The client MUST NOT send a WebTransport request until it has received the setting indicating WebTransport support from the server. (3.1)
+
+%% For draft verisons of WebTransport only, the server MUST NOT process any incoming WebTransport requests until the client settings have been received, as the client may be using a version of the WebTransport extension that is different from the one used by the server. (3.1)
+
+%% Because WebTransport over HTTP/3 requires support for HTTP/3 datagrams and the Capsule Protocol, both the client and the server MUST indicate support for HTTP/3 datagrams by sending a SETTINGS_H3_DATAGRAM value set to 1 in their SETTINGS frame (see Section 2.1.1 of [HTTP-DATAGRAM]). (3.1)
+%% @todo settings_h3_datagram_enabled
+
+%% WebTransport over HTTP/3 also requires support for QUIC datagrams. To indicate support, both the client and the server MUST send a max_datagram_frame_size transport parameter with a value greater than 0 (see Section 3 of [QUIC-DATAGRAM]). (3.1)
+%% @todo quic_datagram_enabled (if size is too low the CONNECT stream can be used for capsules)
+
+%% Any WebTransport requests sent by the client without enabling QUIC and HTTP datagrams MUST be treated as malformed by the server, as described in Section 4.1.2 of [HTTP3]. (3.1)
+%% @todo reject_h3_datagram_disabled
+%% @todo reject_quic_datagram_disabled
+
+%% WebTransport over HTTP/3 relies on the RESET_STREAM_AT frame defined in [RESET-STREAM-AT]. To indicate support, both the client and the server MUST enable the extension as described in Section 3 of [RESET-STREAM-AT]. (3.1)
+%% @todo reset_stream_at_enabled
+
+%% 3.2. Extended CONNECT in HTTP/3
+
+%% [RFC8441] defines an extended CONNECT method in Section 4, enabled by the SETTINGS_ENABLE_CONNECT_PROTOCOL setting. That setting is defined for HTTP/3 by [RFC9220]. A server supporting WebTransport over HTTP/3 MUST send both the SETTINGS_WEBTRANSPORT_MAX_SESSIONS setting with a value greater than "0" and the SETTINGS_ENABLE_CONNECT_PROTOCOL setting with a value of "1". (3.2)
+%% @todo settings_enable_connect_protocol_enabled
+%% @todo reject_settings_enable_connect_protocol_disabled
+
+%% 3.3. Creating a New Session
+
+%% As WebTransport sessions are established over HTTP/3, they are identified using the https URI scheme ([HTTP], Section 4.2.2). (3.3)
+
+%% In order to create a new WebTransport session, a client can send an HTTP CONNECT request. The :protocol pseudo-header field ([RFC8441]) MUST be set to webtransport. The :scheme field MUST be https. Both the :authority and the :path value MUST be set; those fields indicate the desired WebTransport server. If the WebTransport session is coming from a browser client, an Origin header [RFC6454] MUST be provided within the request; otherwise, the header is OPTIONAL. (3.3)
+
+%% If it does not (have a WT server), it SHOULD reply with status code 404 (Section 15.5.5 of [HTTP]). (3.3)
+
+%% When the request contains the Origin header, the WebTransport server MUST verify the Origin header to ensure that the specified origin is allowed to access the server in question. If the verification fails, the WebTransport server SHOULD reply with status code 403 (Section 15.5.4 of [HTTP]). (3.3)
+
+accept_session_when_enabled(Config) ->
+	doc("Confirm that a WebTransport session can be established over HTTP/3. "
+		"(draft_webtrans_http3 3.3, RFC9220)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send Hello, get Hello back.
+	{ok, BidiStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(BidiStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(BidiStreamRef),
+	ok.
+
+%% If the server accepts 0-RTT, the server MUST NOT reduce the limit of maximum open WebTransport sessions from the one negotiated during the previous session; such change would be deemed incompatible, and MUST result in a H3_SETTINGS_ERROR connection error. (3.3)
+
+%% The capsule-protocol header field Section 3.4 of [HTTP-DATAGRAM] is not required by WebTransport and can safely be ignored by WebTransport endpoints. (3.3)
+
+%% 3.4. Application Protocol Negotiation
+
+application_protocol_negotiation(Config) ->
+	doc("Applications can negotiate a protocol to use via WebTransport. "
+		"(draft_webtrans_http3 3.4)"),
+	%% Connect to the WebTransport server.
+	WTAvailableProtocols = cow_http_hd:wt_available_protocols([<<"foo">>, <<"bar">>]),
+	#{
+		resp_headers := RespHeaders
+	} = do_webtransport_connect(Config, [{<<"wt-available-protocols">>, WTAvailableProtocols}]),
+	{<<"wt-protocol">>, WTProtocol} = lists:keyfind(<<"wt-protocol">>, 1, RespHeaders),
+	<<"foo">> = iolist_to_binary(cow_http_hd:parse_wt_protocol(WTProtocol)),
+	ok.
+
+%% Both WT-Available-Protocols and WT-Protocol are Structured Fields [RFC8941]. WT-Available-Protocols is a List of Tokens, and WT-Protocol is a Token. The token in the WT-Protocol response header field MUST be one of the tokens listed in WT-Available-Protocols of the request. (3.4)
+
+%% @todo 3.5 Prioritization
+
+%% 4. WebTransport Features
+
+%% The client MAY optimistically open unidirectional and bidirectional streams, as well as send datagrams, for a session that it has sent the CONNECT request for, even if it has not yet received the server's response to the request. (4)
+
+%% If at any point a session ID is received that cannot be a valid ID for a client-initiated bidirectional stream, the recipient MUST close the connection with an H3_ID_ERROR error code. (4)
+%% @todo Open bidi with Session ID 0, then do the CONNECT request.
+
+%% 4.1. Unidirectional streams
+
+unidirectional_streams(Config) ->
+	doc("Both endpoints can open and use unidirectional streams. "
+		"(draft_webtrans_http3 4.1)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a unidi stream, send Hello with a Fin flag.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn,
+		#{open_flag => ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL}),
+	{ok, _} = quicer:send(LocalStreamRef,
+		<<1:2, 16#54:14, 0:2, SessionID:6, "Hello">>,
+		?QUIC_SEND_FLAG_FIN),
+	%% Accept an identical unidi stream.
+	{unidi, RemoteStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#54:14, 0:2, SessionID:6>>} = do_receive_data(RemoteStreamRef),
+	{fin, <<"Hello">>} = do_receive_data(RemoteStreamRef),
+	ok.
+
+%% 4.2. Bidirectional Streams
+
+bidirectional_streams_client(Config) ->
+	doc("The WT client can open and use bidirectional streams. "
+		"(draft_webtrans_http3 4.2)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send Hello, get Hello back.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(LocalStreamRef),
+	ok.
+
+bidirectional_streams_server(Config) ->
+	doc("The WT server can open and use bidirectional streams. "
+		"(draft_webtrans_http3 4.2)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction
+	%% to make the server create another bidi stream.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:open_bidi">>),
+	%% Accept the bidi stream and receive the data.
+	{bidi, RemoteStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#41:14, 0:2, SessionID:6>>} = do_receive_data(RemoteStreamRef),
+	{ok, _} = quicer:send(RemoteStreamRef, <<"Hello">>,
+		?QUIC_SEND_FLAG_FIN),
+	{fin, <<"Hello">>} = do_receive_data(RemoteStreamRef),
+	ok.
+
+%% Endpoints MUST NOT send WEBTRANSPORT_STREAM as a frame type on HTTP/3 streams other than the very first bytes of a request stream. Receiving this frame type in any other circumstances MUST be treated as a connection error of type H3_FRAME_ERROR. (4.2)
+
+%% 4.3. Resetting Data Streams
+
+%% A WebTransport endpoint may send a RESET_STREAM or a STOP_SENDING frame for a WebTransport data stream. Those signals are propagated by the WebTransport implementation to the application. (4.3)
+
+%% A WebTransport application SHALL provide an error code for those operations. (4.3)
+
+%% WebTransport implementations MUST use the RESET_STREAM_AT frame [RESET-STREAM-AT] with a Reliable Size set to at least the size of the WebTransport header when resetting a WebTransport data stream. This ensures that the ID field associating the data stream with a WebTransport session is always delivered. (4.3)
+
+%% WebTransport implementations SHALL forward the error code for a stream associated with a known session to the application that owns that session (4.3)
+
+%% 4.4. Datagrams
+
+datagrams(Config) ->
+	doc("Both endpoints can send and receive datagrams. (draft_webtrans_http3 4.4)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	QuarterID = SessionID div 4,
+	%% Send a Hello datagram.
+	{ok, _} = quicer:send_dgram(Conn, <<0:2, QuarterID:6, "Hello">>),
+	%% Receive a Hello datagram back.
+	{datagram, SessionID, <<"Hello">>} = do_receive_datagram(Conn),
+	ok.
+
+%% @todo datagrams_via_capsule?
+
+%% 4.5. Buffering Incoming Streams and Datagrams
+
+%% To handle this case (out of order stream_open/CONNECT), WebTransport endpoints SHOULD buffer streams and datagrams until those can be associated with an established session. (4.5)
+
+%% To avoid resource exhaustion, the endpoints MUST limit the number of buffered streams and datagrams. When the number of buffered streams is exceeded, a stream SHALL be closed by sending a RESET_STREAM and/or STOP_SENDING with the WEBTRANSPORT_BUFFERED_STREAM_REJECTED error code. When the number of buffered datagrams is exceeded, a datagram SHALL be dropped. It is up to an implementation to choose what stream or datagram to discard. (4.5)
+
+%% 4.6. Interaction with HTTP/3 GOAWAY frame
+
+%% A client receiving GOAWAY cannot initiate CONNECT requests for new WebTransport sessions on that HTTP/3 connection; it must open a new HTTP/3 connection to initiate new WebTransport sessions with the same peer. (4.6)
+
+%% An HTTP/3 GOAWAY frame is also a signal to applications to initiate shutdown for all WebTransport sessions. (4.6)
+
+%% @todo Currently receipt of a GOAWAY frame immediately ends the connection.
+%%       We want to allow WT sessions to gracefully shut down before that.
+%goaway_client(Config) ->
+%	doc("The HTTP/3 client can initiate the close of all WT sessions "
+%		"by sending a GOAWAY frame. (draft_webtrans_http3 4.6)"),
+%	%% Connect to the WebTransport server.
+%	#{
+%		conn := Conn,
+%		connect_stream_ref := ConnectStreamRef,
+%		session_id := SessionID
+%	} = do_webtransport_connect(Config),
+%	%% Open a control stream and send a GOAWAY frame.
+%	{ok, ControlRef} = quicer:start_stream(Conn,
+%		#{open_flag => ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL}),
+%	{ok, SettingsBin, _HTTP3Machine0} = cow_http3_machine:init(client, #{}),
+%	{ok, _} = quicer:send(ControlRef, [
+%		<<0>>, %% CONTROL stream.
+%		SettingsBin,
+%		<<7>>, %% GOAWAY frame.
+%		cow_http3:encode_int(1),
+%		cow_http3:encode_int(0)
+%	]),
+%	%% Receive a datagram indicating processing by the WT handler.
+%	{datagram, SessionID, <<"TEST:close_initiated">>} = do_receive_datagram(Conn),
+%	ok.
+
+wt_drain_session_client(Config) ->
+	doc("The WT client can initiate the close of a single session. "
+		"(draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Send the WT_DRAIN_SESSION capsule on the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef, cow_capsule:wt_drain_session()),
+	%% Receive a datagram indicating processing by the WT handler.
+	{datagram, SessionID, <<"TEST:close_initiated">>} = do_receive_datagram(Conn),
+	ok.
+
+wt_drain_session_server(Config) ->
+	doc("The WT server can initiate the close of a single session. "
+		"(draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it initiate the close.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:initiate_close">>),
+	%% Receive the WT_DRAIN_SESSION capsule on the CONNECT stream.
+	DrainWTSessionCapsule = cow_capsule:wt_drain_session(),
+	{nofin, DrainWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	ok.
+
+wt_drain_session_continue_client(Config) ->
+	doc("After the WT client has initiated the close of the session, "
+		"both client and server can continue using the session and "
+		"open new streams. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Send the WT_DRAIN_SESSION capsule on the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef, cow_capsule:wt_drain_session()),
+	%% Receive a datagram indicating processing by the WT handler.
+	{datagram, SessionID, <<"TEST:close_initiated">>} = do_receive_datagram(Conn),
+	%% Create a new bidi stream, send Hello, get Hello back.
+	{ok, ContinueStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(ContinueStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(ContinueStreamRef),
+	ok.
+
+wt_drain_session_continue_server(Config) ->
+	doc("After the WT server has initiated the close of the session, "
+		"both client and server can continue using the session and "
+		"open new streams. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it initiate the close.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:initiate_close">>),
+	%% Receive the WT_DRAIN_SESSION capsule on the CONNECT stream.
+	DrainWTSessionCapsule = cow_capsule:wt_drain_session(),
+	{nofin, DrainWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	%% Create a new bidi stream, send Hello, get Hello back.
+	{ok, ContinueStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(ContinueStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(ContinueStreamRef),
+	ok.
+
+%% @todo 4.7. Use of Keying Material Exporters
+
+%% 5. Flow Control
+
+%% 5.1. Limiting the Number of Simultaneous Sessions
+
+%% This document defines a SETTINGS_WEBTRANSPORT_MAX_SESSIONS parameter that allows the server to limit the maximum number of concurrent WebTransport sessions on a single HTTP/3 connection. The client MUST NOT open more simultaneous sessions than indicated in the server SETTINGS parameter. The server MUST NOT close the connection if the client opens sessions exceeding this limit, as the client and the server do not have a consistent view of how many sessions are open due to the asynchronous nature of the protocol; instead, it MUST reset all of the CONNECT streams it is not willing to process with the H3_REQUEST_REJECTED status defined in [HTTP3]. (5.1)
+
+%% 5.2. Limiting the Number of Streams Within a Session
+
+%% The WT_MAX_STREAMS capsule (Section 5.6.1) establishes a limit on the number of streams within a WebTransport session. (5.2)
+
+%% Note that the CONNECT stream for the session is not included in either the bidirectional or the unidirectional stream limits (5.2)
+
+%% The session-level stream limit applies in addition to the QUIC MAX_STREAMS frame, which provides a connection-level stream limit. New streams can only be created within the session if both the stream- and the connection-level limit permit (5.2)
+
+%% The WT_STREAMS_BLOCKED capsule (Section 5.7) can be sent to indicate that an endpoint was unable to create a stream due to the session-level stream limit. (5.2)
+
+%% Note that enforcing this limit requires reliable resets for stream headers so that both endpoints can agree on the number of streams that are open. (5.2)
+
+%% 5.3. Data Limits
+
+%% The WT_MAX_DATA capsule (Section 5.8) establishes a limit on the amount of data that can be sent within a WebTransport session. This limit counts all data that is sent on streams of the corresponding type, excluding the stream header (see Section 4.1 and Section 4.2). (5.3)
+
+%% Implementing WT_MAX_DATA requires that the QUIC stack provide the WebTransport implementation with information about the final size of streams; see { {Section 4.5 of !RFC9000}}. This allows both endpoints to agree on how much data was consumed by that stream, although the stream header exclusion above applies. (5.3)
+
+%% The WT_DATA_BLOCKED capsule (Section 5.9) can be sent to indicate that an endpoint was unable to send data due to a limit set by the WT_MAX_DATA capsule. (5.3)
+
+%% The WT_MAX_STREAM_DATA and WT_STREAM_DATA_BLOCKED capsules (Part XX of [I-D.ietf-webtrans-http2]) are not used and so are prohibited. Endpoints MUST treat receipt of a WT_MAX_STREAM_DATA or a WT_STREAM_DATA_BLOCKED capsule as a session error. (5.3)
+
+%% 5.4. Flow Control and Intermediaries
+
+%% In practice, an intermediary that translates flow control signals between similar WebTransport protocols, such as between two HTTP/3 connections, can often simply reexpress the same limits received on one connection directly on the other connection. (5.4)
+
+%% 5.5. Flow Control SETTINGS
+
+%% WT_MAX_STREAMS via SETTINGS_WEBTRANSPORT_INITIAL_MAX_STREAMS_UNI and SETTINGS_WEBTRANSPORT_INITIAL_MAX_STREAMS_BIDI (5.5)
+
+%% WT_MAX_DATA via SETTINGS_WEBTRANSPORT_INITIAL_MAX_DATA (5.5)
+
+%% 5.6. Flow Control Capsules
+
+%% 5.6.1. WT_MAX_STREAMS Capsule
+
+%% An HTTP capsule [HTTP-DATAGRAM] called WT_MAX_STREAMS is introduced to inform the peer of the cumulative number of streams of a given type it is permitted to open. A WT_MAX_STREAMS capsule with a type of 0x190B4D3F applies to bidirectional streams, and a WT_MAX_STREAMS capsule with a type of 0x190B4D40 applies to unidirectional streams. (5.6.1)
+
+%% Note that, because Maximum Streams is a cumulative value representing the total allowed number of streams, including previously closed streams, endpoints repeatedly send new WT_MAX_STREAMS capsules with increasing Maximum Streams values as streams are opened. (5.6.1)
+
+%% Maximum Streams: A count of the cumulative number of streams of the corresponding type that can be opened over the lifetime of the session. This value cannot exceed 260, as it is not possible to encode stream IDs larger than 262-1. (5.6.1)
+
+%% An endpoint MUST NOT open more streams than permitted by the current stream limit set by its peer. (5.6.1)
+
+%% Note that this limit includes streams that have been closed as well as those that are open. (5.6.1)
+
+%% Initial values for these limits MAY be communicated by sending non-zero values for SETTINGS_WEBTRANSPORT_INITIAL_MAX_STREAMS_UNI and SETTINGS_WEBTRANSPORT_INITIAL_MAX_STREAMS_BIDI. (5.6.1)
+
+%% 5.7. WT_STREAMS_BLOCKED Capsule
+
+%% A sender SHOULD send a WT_STREAMS_BLOCKED capsule (type=0x190B4D43 for bidi or 0x190B4D44 for unidi) when it wishes to open a stream but is unable to do so due to the maximum stream limit set by its peer. (5.7)
+
+%% 5.8. WT_MAX_DATA Capsule
+
+%% An HTTP capsule [HTTP-DATAGRAM] called WT_MAX_DATA (type=0x190B4D3D) is introduced to inform the peer of the maximum amount of data that can be sent on the WebTransport session as a whole. (5.8)
+
+%% This limit counts all data that is sent on streams of the corresponding type, excluding the stream header (see Section 4.1 and Section 4.2). Implementing WT_MAX_DATA requires that the QUIC stack provide the WebTransport implementation with information about the final size of streams; see Section 4.5 of [RFC9000]. (5.8)
+
+%% All data sent in WT_STREAM capsules counts toward this limit. The sum of the lengths of Stream Data fields in WT_STREAM capsules MUST NOT exceed the value advertised by a receiver. (5.8)
+
+%% The initial value for this limit MAY be communicated by sending a non-zero value for SETTINGS_WEBTRANSPORT_INITIAL_MAX_DATA. (5.8)
+
+%% 5.9. WT_DATA_BLOCKED Capsule
+
+%% A sender SHOULD send a WT_DATA_BLOCKED capsule (type=0x190B4D41) when it wishes to send data but is unable to do so due to WebTransport session-level flow control. (5.9)
+
+%% WT_DATA_BLOCKED capsules can be used as input to tuning of flow control algorithms. (5.9)
+
+%% 6. Session Termination
+
+%% A WebTransport session over HTTP/3 is considered terminated when either of the following conditions is met:
+%% * the CONNECT stream is closed, either cleanly or abruptly, on either side; or
+%% * a WT_CLOSE_SESSION capsule is either sent or received.
+%% (6)
+
+wt_close_session_client(Config) ->
+	doc("The WT client can close a single session. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		connect_stream_ref := ConnectStreamRef
+	} = do_webtransport_connect(Config),
+	%% Send the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef,
+		cow_capsule:wt_close_session(0, <<>>),
+		?QUIC_SEND_FLAG_FIN),
+	%% Normally we should also stop reading but in order to detect
+	%% that the server stops the stream we must not otherwise the
+	%% stream will be de facto closed on our end.
+	%%
+	%% The recipient must close or reset the stream in response.
+	receive
+		{quic, stream_closed, ConnectStreamRef, _} ->
+			ok
+	after 1000 ->
+		error({timeout, waiting_for_stream_closed})
+	end.
+
+wt_close_session_server(Config) ->
+	doc("The WT server can close a single session. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it initiate the close.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:close">>),
+	%% Receive the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	CloseWTSessionCapsule = cow_capsule:wt_close_session(0, <<>>),
+	{fin, CloseWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	ok.
+
+wt_session_gone_client(Config) ->
+	doc("Upon learning that the session has been terminated, "
+		"the WT server must reset associated streams with the "
+		"WEBTRANSPORT_SESSION_GONE error code. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a unidi stream.
+	{ok, LocalUnidiStreamRef} = quicer:start_stream(Conn,
+		#{open_flag => ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL}),
+	{ok, _} = quicer:send(LocalUnidiStreamRef,
+		<<1:2, 16#54:14, 0:2, SessionID:6, "Hello">>),
+	%% Accept an identical unidi stream.
+	{unidi, RemoteUnidiStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#54:14, 0:2, SessionID:6>>} = do_receive_data(RemoteUnidiStreamRef),
+	{nofin, <<"Hello">>} = do_receive_data(RemoteUnidiStreamRef),
+	%% Create a bidi stream, send a special instruction
+	%% to make the server create another bidi stream.
+	{ok, LocalBidiStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalBidiStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:open_bidi">>),
+	%% Accept the bidi stream and receive the data.
+	{bidi, RemoteBidiStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#41:14, 0:2, SessionID:6>>} = do_receive_data(RemoteBidiStreamRef),
+	{ok, _} = quicer:send(RemoteBidiStreamRef, <<"Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(RemoteBidiStreamRef),
+	%% Send the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef,
+		cow_capsule:wt_close_session(0, <<>>),
+		?QUIC_SEND_FLAG_FIN),
+	%% All streams from that WT session have been aborted.
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(LocalUnidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(RemoteUnidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(LocalBidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(RemoteBidiStreamRef),
+	ok.
+
+wt_session_gone_server(Config) ->
+	doc("After the session has been terminated by the WT server, "
+		"the WT server must reset associated streams with the "
+		"WEBTRANSPORT_SESSION_GONE error code. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a unidi stream.
+	{ok, LocalUnidiStreamRef} = quicer:start_stream(Conn,
+		#{open_flag => ?QUIC_STREAM_OPEN_FLAG_UNIDIRECTIONAL}),
+	{ok, _} = quicer:send(LocalUnidiStreamRef,
+		<<1:2, 16#54:14, 0:2, SessionID:6, "Hello">>),
+	%% Accept an identical unidi stream.
+	{unidi, RemoteUnidiStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#54:14, 0:2, SessionID:6>>} = do_receive_data(RemoteUnidiStreamRef),
+	{nofin, <<"Hello">>} = do_receive_data(RemoteUnidiStreamRef),
+	%% Create a bidi stream, send a special instruction
+	%% to make the server create another bidi stream.
+	{ok, LocalBidiStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalBidiStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6, "TEST:open_bidi">>),
+	%% Accept the bidi stream and receive the data.
+	{bidi, RemoteBidiStreamRef} = do_receive_new_stream(),
+	{nofin, <<1:2, 16#41:14, 0:2, SessionID:6>>} = do_receive_data(RemoteBidiStreamRef),
+	{ok, _} = quicer:send(RemoteBidiStreamRef, <<"Hello">>),
+	{nofin, <<"Hello">>} = do_receive_data(RemoteBidiStreamRef),
+
+	%% Send a special instruction to make the server initiate the close.
+	{ok, _} = quicer:send(LocalBidiStreamRef, <<"TEST:close">>),
+	%% Receive the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	CloseWTSessionCapsule = cow_capsule:wt_close_session(0, <<>>),
+	{fin, CloseWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	%% All streams from that WT session have been aborted.
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(LocalUnidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(RemoteUnidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(LocalBidiStreamRef),
+	#{reason := webtransport_session_gone} = do_wait_stream_aborted(RemoteBidiStreamRef),
+	ok.
+
+%% Application Error Message: A UTF-8 encoded error message string provided by the application closing the session. The message takes up the remainder of the capsule, and its length MUST NOT exceed 1024 bytes. (6)
+%% @todo What if it's larger?
+
+wt_close_session_app_code_msg_client(Config) ->
+	doc("The WT client can close a single session with an application error code "
+		"and an application error message. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it propagate events.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	EventPidBin = term_to_binary(self()),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:event_pid:", EventPidBin/binary>>),
+	%% Send the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef,
+		cow_capsule:wt_close_session(17, <<"seventeen">>),
+		?QUIC_SEND_FLAG_FIN),
+	%% @todo Stop reading from the CONNECt stream too. (STOP_SENDING)
+	%% Receive the terminate event from the WT handler.
+	receive
+		{'$wt_echo_h', terminate, {closed, 17, <<"seventeen">>}, _, _} ->
+			ok
+	after 1000 ->
+		error({timeout, waiting_for_terminate_event})
+	end.
+
+wt_close_session_app_code_server(Config) ->
+	doc("The WT server can close a single session with an application error code. "
+		"(draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it initiate the close.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:close_app_code">>),
+	%% Receive the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	CloseWTSessionCapsule = cow_capsule:wt_close_session(1234567890, <<>>),
+	{fin, CloseWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	ok.
+
+wt_close_session_app_code_msg_server(Config) ->
+	doc("The WT server can close a single session with an application error code "
+		"and an application error message. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it initiate the close.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:close_app_code_msg">>),
+	%% Receive the WT_CLOSE_SESSION capsule on the CONNECT stream.
+	CloseWTSessionCapsule = iolist_to_binary(cow_capsule:wt_close_session(1234567890,
+		<<"onetwothreefourfivesixseveneightnineten">>)),
+	{fin, CloseWTSessionCapsule} = do_receive_data(ConnectStreamRef),
+	ok.
+
+%% An endpoint that sends a WT_CLOSE_SESSION capsule MUST immediately send a FIN. The endpoint MAY send a STOP_SENDING to indicate it is no longer reading from the CONNECT stream. The recipient MUST either close or reset the stream in response. (6)
+%% @todo wt_close_session_server_fin
+%% @todo The part about close/reset should be tested in wt_close_session_client.
+
+%% If any additional stream data is received on the CONNECT stream after receiving a WT_CLOSE_SESSION capsule, the stream MUST be reset with code H3_MESSAGE_ERROR. (6)
+%% @todo wt_close_session_followed_by_data
+
+connect_stream_closed_cleanly_fin(Config) ->
+	doc("The WT client closing the CONNECT stream cleanly "
+		"is equivalent to a capsule with an application error code of 0 "
+		"and an empty error string. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it propagate events.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	EventPidBin = term_to_binary(self()),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:event_pid:", EventPidBin/binary>>),
+	{nofin, <<"event_pid_received">>} = do_receive_data(LocalStreamRef),
+	%% Cleanly terminate the CONNECT stream.
+	{ok, _} = quicer:send(ConnectStreamRef, <<>>, ?QUIC_SEND_FLAG_FIN),
+	%% Receive the terminate event from the WT handler.
+	receive
+		{'$wt_echo_h', terminate, {closed, 0, <<>>}, _, _} ->
+			ok
+	after 1000 ->
+		error({timeout, waiting_for_terminate_event})
+	end.
+
+connect_stream_closed_cleanly_shutdown(Config) ->
+	doc("The WT client closing the CONNECT stream cleanly "
+		"is equivalent to a capsule with an application error code of 0 "
+		"and an empty error string. (draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it propagate events.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	EventPidBin = term_to_binary(self()),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:event_pid:", EventPidBin/binary>>),
+	{nofin, <<"event_pid_received">>} = do_receive_data(LocalStreamRef),
+	%% Cleanly terminate the CONNECT stream.
+	_ = quicer:shutdown_stream(ConnectStreamRef),
+	%% Receive the terminate event from the WT handler.
+	receive
+		{'$wt_echo_h', terminate, {closed, 0, <<>>}, _, _} ->
+			ok
+	after 1000 ->
+		error({timeout, waiting_for_terminate_event})
+	end.
+
+connect_stream_closed_abruptly(Config) ->
+	doc("The WT client may close the CONNECT stream abruptly. "
+		"(draft_webtrans_http3 4.6)"),
+	%% Connect to the WebTransport server.
+	#{
+		conn := Conn,
+		connect_stream_ref := ConnectStreamRef,
+		session_id := SessionID
+	} = do_webtransport_connect(Config),
+	%% Create a bidi stream, send a special instruction to make it propagate events.
+	{ok, LocalStreamRef} = quicer:start_stream(Conn, #{}),
+	EventPidBin = term_to_binary(self()),
+	{ok, _} = quicer:send(LocalStreamRef, <<1:2, 16#41:14, 0:2, SessionID:6,
+		"TEST:event_pid:", EventPidBin/binary>>),
+	{nofin, <<"event_pid_received">>} = do_receive_data(LocalStreamRef),
+	%% Abruptly terminate the CONNECT stream.
+	_ = quicer:shutdown_stream(ConnectStreamRef, ?QUIC_STREAM_SHUTDOWN_FLAG_ABORT,
+		0, infinity),
+	%% Receive the terminate event from the WT handler.
+	receive
+		%% @todo It would be good to forward a stream error as well
+		%%       so that a WT error can be sent, but I have been unsuccessful.
+		{'$wt_echo_h', terminate, closed_abruptly, _, _} ->
+			ok
+	after 1000 ->
+		error({timeout, waiting_for_terminate_event})
+	end.
+
+%% @todo This one is about gracefully closing HTTP/3 connection with WT sessions.
+%% the endpoint SHOULD wait until all CONNECT streams have been closed by the peer before sending the CONNECTION_CLOSE (6)
+
+%% Helpers.
+
+do_webtransport_connect(Config) ->
+	do_webtransport_connect(Config, []).
+
+do_webtransport_connect(Config, ExtraHeaders) ->
+	%% Connect to server.
+	#{conn := Conn, settings := Settings} = rfc9114_SUITE:do_connect(Config, #{
+		peer_unidi_stream_count => 100,
+		datagram_send_enabled => 1,
+		datagram_receive_enabled => 1
+	}),
+	%% Confirm that SETTINGS_ENABLE_CONNECT_PROTOCOL = 1.
+	#{enable_connect_protocol := true} = Settings,
+	%% Confirm that SETTINGS_WEBTRANSPORT_MAX_SESSIONS >= 1.
+	#{webtransport_max_sessions := WTMaxSessions} = Settings,
+	true = WTMaxSessions >= 1,
+	%% Confirm that SETTINGS_H3_DATAGRAM = 1.
+	#{h3_datagram := true} = Settings,
+	%% Confirm that QUIC's max_datagram_size > 0.
+	receive {quic, dgram_state_changed, Conn, DatagramState} ->
+		#{
+			dgram_max_len := DatagramMaxLen,
+			dgram_send_enabled := DatagramSendEnabled
+		} = DatagramState,
+		true = DatagramMaxLen > 0,
+		true = DatagramSendEnabled,
+		ok
+	after 5000 ->
+		error({timeout, waiting_for_datagram_state_change})
+	end,
+	%% Send a CONNECT :protocol request to upgrade the stream to Websocket.
+	{ok, ConnectStreamRef} = quicer:start_stream(Conn, #{}),
+	{ok, EncodedRequest, _EncData, _EncSt} = cow_qpack:encode_field_section([
+		{<<":method">>, <<"CONNECT">>},
+		{<<":protocol">>, <<"webtransport">>},
+		{<<":scheme">>, <<"https">>},
+		{<<":path">>, <<"/wt">>},
+		{<<":authority">>, <<"localhost">>}, %% @todo Correct port number.
+		{<<"origin">>, <<"https://localhost">>}
+	|ExtraHeaders], 0, cow_qpack:init(encoder)),
+	{ok, _} = quicer:send(ConnectStreamRef, [
+		<<1>>, %% HEADERS frame.
+		cow_http3:encode_int(iolist_size(EncodedRequest)),
+		EncodedRequest
+	]),
+	%% Receive a 200 response.
+	{nofin, Data} = do_receive_data(ConnectStreamRef),
+	{HLenEnc, HLenBits} = rfc9114_SUITE:do_guess_int_encoding(Data),
+	<<
+		1, %% HEADERS frame.
+		HLenEnc:2, HLen:HLenBits,
+		EncodedResponse:HLen/bytes
+	>> = Data,
+	{ok, DecodedResponse, _DecData, _DecSt}
+		= cow_qpack:decode_field_section(EncodedResponse, 0, cow_qpack:init(decoder)),
+	#{<<":status">> := <<"200">>} = maps:from_list(DecodedResponse),
+	%% Retrieve the Session ID.
+	{ok, SessionID} = quicer:get_stream_id(ConnectStreamRef),
+	%% Accept QPACK streams to avoid conflicts with unidi streams from tests.
+	Unidi1 = rfc9114_SUITE:do_accept_qpack_stream(Conn),
+	Unidi2 = rfc9114_SUITE:do_accept_qpack_stream(Conn),
+	%% Done.
+	#{
+		conn => Conn,
+		connect_stream_ref => ConnectStreamRef,
+		session_id => SessionID,
+		resp_headers => DecodedResponse,
+		enc_or_dec1 => Unidi1,
+		enc_or_dec2 => Unidi2
+	}.
+
+do_receive_new_stream() ->
+	receive
+		{quic, new_stream, StreamRef, #{flags := Flags}} ->
+			ok = quicer:setopt(StreamRef, active, true),
+			case quicer:is_unidirectional(Flags) of
+				true -> {unidi, StreamRef};
+				false -> {bidi, StreamRef}
+			end
+	after 5000 ->
+		error({timeout, waiting_for_stream})
+	end.
+
+do_receive_data(StreamRef) ->
+	receive {quic, Data, StreamRef, #{flags := Flags}} ->
+		IsFin = case Flags band ?QUIC_RECEIVE_FLAG_FIN of
+			?QUIC_RECEIVE_FLAG_FIN -> fin;
+			_ -> nofin
+		end,
+		{IsFin, Data}
+	after 5000 ->
+		error({timeout, waiting_for_data})
+	end.
+
+do_receive_datagram(Conn) ->
+	receive {quic, <<0:2, QuarterID:6, Data/bits>>, Conn, Flags} when is_integer(Flags) ->
+		{datagram, QuarterID * 4, Data}
+	after 5000 ->
+		ct:pal("~p", [process_info(self(), messages)]),
+		error({timeout, waiting_for_datagram})
+	end.
+
+-endif.
--- a/test/handlers/wt_echo_h.erl
+++ b/test/handlers/wt_echo_h.erl
@ -0,0 +1,103 @@
+%% This module echoes client events back,
+%% including creating new streams.
+
+-module(wt_echo_h).
+-behavior(cowboy_webtransport).
+
+-export([init/2]).
+-export([webtransport_handle/2]).
+-export([webtransport_info/2]).
+-export([terminate/3]).
+
+%% -define(DEBUG, 1).
+-ifdef(DEBUG).
+-define(LOG(Fmt, Args), ct:pal(Fmt, Args)).
+-else.
+-define(LOG(Fmt, Args), _ = Fmt, _ = Args, ok).
+-endif.
+
+init(Req0, _) ->
+	?LOG("WT init ~p~n", [Req0]),
+	Req = case cowboy_req:parse_header(<<"wt-available-protocols">>, Req0) of
+		undefined ->
+			Req0;
+		[Protocol|_] ->
+			cowboy_req:set_resp_header(<<"wt-protocol">>, cow_http_hd:wt_protocol(Protocol), Req0)
+	end,
+	{cowboy_webtransport, Req, #{}}.
+
+webtransport_handle(Event = {stream_open, StreamID, bidi}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	{[], Streams#{StreamID => bidi}};
+webtransport_handle(Event = {stream_open, StreamID, unidi}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	OpenStreamRef = make_ref(),
+	{[{open_stream, OpenStreamRef, unidi, <<>>}], Streams#{
+		StreamID => {unidi_remote, OpenStreamRef},
+		OpenStreamRef => {unidi_local, StreamID}}};
+webtransport_handle(Event = {opened_stream_id, OpenStreamRef, OpenStreamID}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	case Streams of
+		#{OpenStreamRef := bidi} ->
+			{[], maps:remove(OpenStreamRef, Streams#{
+				OpenStreamID => bidi
+			})};
+		#{OpenStreamRef := {unidi_local, RemoteStreamID}} ->
+			#{RemoteStreamID := {unidi_remote, OpenStreamRef}} = Streams,
+			{[], maps:remove(OpenStreamRef, Streams#{
+				RemoteStreamID => {unidi_remote, OpenStreamID},
+				OpenStreamID => {unidi_local, RemoteStreamID}
+			})}
+	end;
+webtransport_handle(Event = {stream_data, StreamID, _IsFin, <<"TEST:", Test/bits>>}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	case Test of
+		<<"open_bidi">> ->
+			OpenStreamRef = make_ref(),
+			{[{open_stream, OpenStreamRef, bidi, <<>>}],
+				Streams#{OpenStreamRef => bidi}};
+		<<"initiate_close">> ->
+			{[initiate_close], Streams};
+		<<"close">> ->
+			{[close], Streams};
+		<<"close_app_code">> ->
+			{[{close, 1234567890}], Streams};
+		<<"close_app_code_msg">> ->
+			{[{close, 1234567890, <<"onetwothreefourfivesixseveneightnineten">>}], Streams};
+		<<"event_pid:", EventPidBin/bits>> ->
+			{[{send, StreamID, nofin, <<"event_pid_received">>}],
+				Streams#{event_pid => binary_to_term(EventPidBin)}}
+	end;
+webtransport_handle(Event = {stream_data, StreamID, IsFin, Data}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	case Streams of
+		#{StreamID := bidi} ->
+			{[{send, StreamID, IsFin, Data}], Streams};
+		#{StreamID := {unidi_remote, Ref}} when is_reference(Ref) ->
+			%% The stream isn't ready. We try again later.
+			erlang:send_after(100, self(), {try_again, Event}),
+			{[], Streams};
+		#{StreamID := {unidi_remote, LocalStreamID}} ->
+			{[{send, LocalStreamID, IsFin, Data}], Streams}
+	end;
+webtransport_handle(Event = {datagram, Data}, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	{[{send, datagram, Data}], Streams};
+webtransport_handle(Event = close_initiated, Streams) ->
+	?LOG("WT handle ~p~n", [Event]),
+	{[{send, datagram, <<"TEST:close_initiated">>}], Streams};
+webtransport_handle(Event, Streams) ->
+	?LOG("WT handle ignore ~p~n", [Event]),
+	{[], Streams}.
+
+webtransport_info({try_again, Event}, Streams) ->
+	?LOG("WT try_again ~p", [Event]),
+	webtransport_handle(Event, Streams).
+
+terminate(Reason, Req, State=#{event_pid := EventPid}) ->
+	?LOG("WT terminate ~0p~n~0p~n~0p", [Reason, Req, State]),
+	EventPid ! {'$wt_echo_h', terminate, Reason, Req, State},
+	ok;
+terminate(Reason, Req, State) ->
+	?LOG("WT terminate ~0p~n~0p~n~0p", [Reason, Req, State]),
+	ok.
--- a/test/rfc9220_SUITE.erl
+++ b/test/rfc9220_SUITE.erl
@ -426,7 +426,7 @@ reject_upgrade_header(Config) ->
 % Examples.

 accept_handshake_when_enabled(Config) ->
-	doc("Confirm the example for Websocket over HTTP/2 works. (RFC9220, RFC8441 5.1)"),
+	doc("Confirm the example for Websocket over HTTP/3 works. (RFC9220, RFC8441 5.1)"),
 	%% Connect to server and confirm that SETTINGS_ENABLE_CONNECT_PROTOCOL = 1.
 	#{conn := Conn, settings := Settings} = rfc9114_SUITE:do_connect(Config),
 	#{enable_connect_protocol := true} = Settings,